per asp gespeicherte prozedur auf SQL Server aufrufen!!

[Martin Speiser]

Hi Eldrik,

zu meinem Problem wie kann ich per asp eine gespeicherte Prozedur auf einem SQL- Server aufrufen, und dieser durch ein Formular eingegebene Daten zukommen lassen? Die diese für die Verarbeitung benötigt?

mit den drei Funktionen geht's:

<%
function AdoCreateConnection( strDBConnect )

Dim adoConn
  set adoConn = Server.CreateObject( "ADODB.Connection" )

with adoConn
    .ConnectionString = strDBConnect
    .CursorLocation = 3 ' ADODB.adUseClient
    .Open
  end with

set AdoCreateConnection = adoConn

end function

function AdoCreateCommandSP( strDBConnect, strStoredProcName )

Dim adoCmd
  Set adoCmd = Server.CreateObject( "ADODB.Command" )

With adoCmd
    Set .ActiveConnection = AdoCreateConnection( strDBConnect )
    .CommandType = 4 ' ADODB.adCmdStoredProc
    .CommandText = strStoredProcName
    .NamedParameters = true
  End With

Set AdoCreateCommandSP = adoCmd

end function

function AdoExecCommandRS( adoCmd )

Dim rs

Set rs = adoCmd.Execute()
  Set rs.ActiveConnection = Nothing

Set AdoExecCommandRS = rs

End Function
%>

Beispielaufruf:

Dim adoCmd
  set adoCmd = AdoCreateCommandSP( strDBConnect, strStoredProcedure )
  with adoCmd
    .Parameters.Refresh
    .Parameters( "@LangID" ).Value    = nLanguageID
  end with

Dim rs
  set rs = AdoExecCommandRS( adoCmd )

set adoCmd = Nothing

Gruß,
Martin