Access und VB-Krams

[Till aus dem Norden]

Hallihallo,

ich versuche gerade, ohne ein gutes Buch mit Access zu arbeiten. Das
sind zwar schon zwei Fehler auf einmal, aber ich hab trotzdem keine
Ahnung, wie ich in einer Prozedur Werte aus meinen Tabellen zur
Weiterverarbeitung in Variablen speichern kann. Die Hilfe ist keine Hilfe,
aber ich will trotzdem ein Ergebnis.

Kann mir jemand helfen? Vielen Dank in jedem Fall

Gruß aus Hamburg,

Till

[Axel Richter]

Hallihallo,

ich versuche gerade, ohne ein gutes Buch mit Access zu arbeiten. Das
sind zwar schon zwei Fehler auf einmal, aber ich hab trotzdem keine
Ahnung, wie ich in einer Prozedur Werte aus meinen Tabellen zur
Weiterverarbeitung in Variablen speichern kann. Die Hilfe ist keine Hilfe,
aber ich will trotzdem ein Ergebnis.

Kann mir jemand helfen? Vielen Dank in jedem Fall

Lege eine Tabelle Tabelle1 an, die mindestens die Felder ID, Name und Vorname hat. Trage ein paar Daten ein. Probiere das folgende VB-Modul

Option Compare Database
Option Explicit

Sub tabelleauslesen()
Dim db As Database
Dim rs As Recordset
Dim tb As TableDef
Dim felder() As String
Dim i As Integer
Dim myID As Integer, myName As String, myVorname As String

Set db = CurrentDb

'Tabelle1 muss existieren
Set tb = db.TableDefs("Tabelle1")
ReDim felder(tb.Fields.Count)
For i = 0 To tb.Fields.Count - 1
    felder(i) = tb.Fields(i).Name
    MsgBox (felder(i))
Next

'Annahme: Tabelle1 enthält die Felder ID, Name, Vorname
Set rs = db.OpenRecordset("SELECT ID, Name, Vorname FROM Tabelle1")
Do While Not rs.EOF
    myID = rs!ID
    myName = rs!Name
    myVorname = rs!Vorname
    MsgBox (myID & myName & myVorname)
    rs.MoveNext
Loop
End Sub

Für den Einstieg in die Hilfefunktion gehst Du wie folgt vor:

Stelle den Cursor in das Wort CurrentDB. Drücke F1. Die Hilfe zur Funktion CurrentDB erscheint. Klicke auf den Link Database. Hier hast Du die Objekthierarchie, beginnend bei Workspace. Nun kannst Du weiter navigieren z.B. zu Recordsets ...

Die Methode - Cursor in ein Schlüsselwort, dann F1 - funktioniert in allen bekannten Schlüsselworten. Also auch bei While, For. ReDim ...

viele Grüße

Axel

[Till]

Vielen lieben Dank!!!

Das hilft mir sehr weiter

gruß
Till